無限之塔腳本問題

DBC · 發表於 2010-5-18 18:43:32

本帖最後由 DBC 於 2010/5/20 02:45 PM 編輯

本來是使用EA13888 模擬器開無限之塔腳本，運作上是都沒問題的

但是改換了 SeAr_1.3.236
無限之塔爬上80樓之後，這時候如果滅團回村，照理來說可以向NPC領取獎勵
但是玩家反應領取不到，去看了一下，map_server_sql.exe跑出了

[渣昫]: npc_click: npc_id != 0

複製代碼

請問我該如何解決這問題呢...?

提供腳本相關原碼

e_tower,75,119,5 script 埃蘭之影 997,{
mes "[埃蘭之影]";
mes "找我有事嗎";
next;
if(@i==80)
{
mes "[埃蘭之影]";
mes "原來你到過80樓";
mes "這些東西就送給你了";
getitem 607,100;
set @i,0;
close;
}

複製代碼

如果需要其他相關資訊請跟我說>"<

sinya · 發表於 2010-5-19 02:08:47

是打死全部的怪才是 80吧減團不是 79而已?

DBC · 發表於 2010-5-19 16:50:02

因為昨天有人爬到85滅團，但是卻領不到獎品囧

但是她們去一樓點領獎npc

系統一直出現npc_click: npc_id != 0

sinya · 發表於 2010-5-19 17:16:06

本帖最後由 sinya 於 2010-5-19 05:29 PM 編輯

npc_click: npc_id != 0
這個跟領不領的到獎沒關係
那是同時執行很多NPC才會出現的

而且你也沒貼出 @i 變數相關腳本
只貼 if(@i==80){領獎}
根本無從看起

DBC · 發表於 2010-5-19 20:17:33

e_tower,71,117,5 script 無限之塔看守人 421,{
if( !getcharid(1) )
{
mes "[無限之塔看守人]";
mes "對不起，您沒有隊伍。";
close;
}
if( getgmlevel()>90 )
{
mes "[無限之塔看守人]";
mes "尊貴的來賓";
mes "你想做什麼？";
next;
switch( select( "重新開始","挑戰","我還沒準備好" ) )
{
case 1:
mes "[無限之塔看守人]";
mes "好的，沒問題.";
close2;
goto OnTimer14410000;
case 2:
mes "[無限之塔看守人]";
mes "了不起，讓我們開始吧！";
close2;
for( set .@i,1; .@i<7; set .@i,.@i+1)
killmonsterall .@i+"@tower";
set .team,getcharid(1);
set .intest,1;
donpcevent "naght::OnRoom1";
warpparty "1@tower",50,355,.team;
initnpctimer;
announce "GM正在測試無限之塔.",bc_all;
close;
case 3:
close;
}
}
if(.intest)
{
mes "[無限之塔看守人]";
mes "GM現在正在測試無限之塔.";
close;
}
if(!.team)
{
if( getcharid(0) != getpartyleader(getcharid(1),2) )
{
mes "[無限之塔看守人]";
mes "對不起，只有隊長才可以登記。";
close;
}
else if( gettimetick(2) - ET_Tower > 43200 )
{
mes "[無限之塔看守人]";
mes "歡迎 "+strcharinfo(0)+".";
mes "你想登記進入無限之塔嗎?";
mes "挑戰需要支付100W";
next;
switch( select( "是的","不要" ) )
{
case 1:
getpartymember(getcharid(1));
if( $@partymembercount < 2 || zeny < 1000000 )
{
mes "[無限之塔看守人]";
mes "對不起，你的隊伍成員必須在二人以上或者金錢不夠.";
close;
}
mes "[無限之塔看守人]";
mes "你只有4個小時的時間.";
mes "4小時後，你和你的全體隊員只有等待12小時後才能重新登記進入無限之塔。";
next;
mes "[無限之塔看守人]";
mes "你確定要登記嗎?";
next;
switch( select( "是的","不要" ) )
{
case 1:
mes "[無限之塔看守人]";
mes "你的隊伍已經成功登記了.";
set zeny,zeny-1000000;
close2;
set .ET_Slot,0;
set .ET_Players$[.ET_Slot],strcharinfo(0);
set .ET_Slot,.ET_Slot+1;
set .team, getcharid(1);
set ET_Tower, gettimetick(2);
set .ET_Tower,1;
getpartymember(getcharid(1));
set .partymembers,$@partymembercount;
announce "無限之塔已經被打開.",bc_all;
mapannounce "e_tower","請"+getpartyname(.team)+"的隊伍成員（不包括隊長）,確認登記.",bc_map;
end;
case 2:
close;
}
case 2:
close;
}
}
else
{
mes "[無限之塔看守人]";
mes "對不起，12小時內不能重複挑戰.";
close;
}
}
else
{
for(set .@i,0; .@i<getarraysize(.ET_Players$); set .@i,.@i+1)
{//in case he signed up
if( .ET_Players$[.@i] == strcharinfo(0) )
{
mes "[無限之塔看守人]";
mes "對不起, 你已經登記過了.";
close;
}
}
if(getcharid(1)!=.team)
{
mes "[無限之塔看守人]";
mes "對不起, 隊員 "+getpartyname(.team)+" 已經登記過了.";
mes "請稍後再來.";
close;
}
else if( .ET_Tower < .partymembers)
{
if(gettimetick(2)-ET_Tower>43200)
{
mes "[無限之塔看守人]";
mes "確認你的登記.";
next;
switch( select( "是","否" ) )
{
case 1:
mes "[無限之塔看守人]";
mes "已經登記成功.";
close2;
set .ET_Players$[.ET_Slot],strcharinfo(0);
set .ET_Slot,.ET_Slot+1;
set ET_Tower,gettimetick(2);
set .ET_Tower, .ET_Tower+1;
mapannounce "e_tower","須登記人數："+.partymembers+" 已登記人數："+.ET_Tower,bc_map;
if(.ET_Tower==.partymembers)
{
mapannounce "e_tower","所有隊員都登記成功，冒險即將開始.",bc_map;
donpcevent "naght::OnRoom1";
warpparty "1@tower",50,355,.team;
initnpctimer;
end;
}
end;
case 2:
close;
}
}
else
{
mes "[無限之塔看守人]";
mes "對不起，你已經登記過了或者上次參加的時間離現在不到12小時.";
close;
}
}
else if( getcharid(0) != getpartyleader(getcharid(1),2) )
{
for(set .@i,0; .@i <= 12; set .@i,.@i + 1 )
{
if(.ET_Players$[.@i] == strcharinfo(0))
{
mes "[無限之塔看守人]";
mes "我將打開一個入口，它會把你傳送到第一層.";
close2;
warp "1@tower",50,355;
end;
}
}
mes "[無限之塔看守人]";
mes "在登記正在處理的過程中，你不能進行登記，所以我不能允許你進入無限之塔。";
close;
}
else
{
mes "[無限之塔看守人]";
mes "你想離開還是回到你的隊友身邊?";
next;
switch( select( "離開.","返回." ) )
{
case 1:
mes "[無限之塔看守人]";
mes "那就這樣吧.";
close2;
set .team,0;
set .ET_Tower,0;
setnpctimer 14404500;
startnpctimer;
end;
case 2:
for(set .@i,0; .@i <= 12; set .@i,.@i + 1 )
{
if(.ET_Players$[.@i] == strcharinfo(0))
{
mes "[無限之塔看守人]";
mes "我將打開一個入口，它會把你傳送到第一層.";
close2;
warp "1@tower",50,355;
end;
}
}
mes "[無限之塔看守人]";
mes "在登記正在處理的過程中，你不能進行登記，所以我不能允許你進入無限之塔。";
close;
}
}
}
OnTimer3600000:
for( set .@i,1; .@i<7; set .@i,.@i+1)
mapannounce .@i+"@tower","還剩3個小時.",bc_map;
end;
OnTimer7200000:
for( set .@i,1; .@i<7; set .@i,.@i+1)
mapannounce .@i+"@tower","還剩2個小時.",bc_map;
end;
OnTimer10800000:
for( set .@i,1; .@i<7; set .@i,.@i+1)
mapannounce .@i+"@tower","還剩1個小時.",bc_map;
end;
OnTimer14400000:
for( set .@i,1; .@i<7; set .@i,.@i+1)
mapannounce .@i+"@tower","時間到，你們將被傳送到天津主城.",bc_map;
end;
OnTimer14405000:
warpparty "prontera",156,181,getvariableofnpc(.team,"無限之塔看守人");
end;
OnTimer14410000:
announce "無限之塔重新開放了",bc_all;
set .team,0;
set .ET_Tower,0;
set .intest,0;
set $@et_award,0;
for( set .@i,1; .@i<7; set .@i,.@i+1)
killmonsterall .@i+"@tower";
for(set .@i,2; .@i<102; set .@i,.@i+1)
disablenpc "ET_Warp_"+.@i;
disablenpc "納戶特基格";
disablenpc "warptonaght1";
disablenpc "warptonaght2";
disablenpc "ET_Exit";
end;
OnInit:
disablenpc "納戶特基格";
disablenpc "warptonaght1";
disablenpc "warptonaght2";
disablenpc "ET_Exit";
for(set .@i,2; .@i<102; set .@i,.@i+1)
disablenpc "ET_Warp_"+.@i;
end;
OnPCLoadMapEvent:
getmapxy(.@m$,.@x,.@y,0);
if( (.@m$ == "1@tower" || .@m$ == "2@tower" || .@m$ == "3@tower" || .@m$ == "4@tower" || .@m$ == "5@tower") )
{
if(!getvariableofnpc(.team,"無限之塔看守人"))
warp "SavePoint",0,0;
if(!@eting)
set @eting,1;
if( getcharid(0)==getpartyleader(getvariableofnpc(.team,"無限之塔看守人"),2) )
{
if( .@m$ == "2@tower" && !($@et_award&1) )
{
getitem 7726,1;
set $@et_award,$@et_award|1;
}
else if( .@m$ == "3@tower" && !($@et_award&2) )
{
getitem 7726,1;
set $@et_award,$@et_award|2;
}
else if( .@m$ == "4@tower" && !($@et_award&4) )
{
getitem 7726,1;
set $@et_award,$@et_award|4;
}
}
}
end;
OnPCLogoutEvent:
if(@eting)
if((getmapusers("1@tower")+getmapusers("2@tower")+getmapusers("3@tower")+getmapusers("4@tower")+getmapusers("5@tower")+getmapusers("6@tower"))==1)
donpcevent "無限之塔看守人::OnTimer14410000";
end;
}

複製代碼

在此提供給您看了

sinya · 發表於 2010-5-19 22:39:37

本帖最後由 sinya 於 2010-5-19 10:43 PM 編輯

你貼錯了吧還是沒主程式沒殺怪事件的? 也找不到@i

還有太長請用附件的排版很亂本來就很難看了又亂掉更看不懂

qqq0963103646 · 發表於 2010-5-19 22:48:57

997,{ 好像有問題太久沒用望瞜

DBC · 發表於 2010-5-19 23:08:32

本帖最後由 DBC 於 2010-5-20 12:26 AM 編輯

檔案上傳給您看了@@

麻煩您了>"<

DBC · 發表於 2010-5-20 00:28:44

感謝sinya 大

照您所說的修改好沒問題了感謝>"<

但是，目前把樓層最後一隻怪物打死還是會出現npc_click: npc_id != 0 @@

sinya · 發表於 2010-5-20 00:38:52

本帖最後由 sinya 於 2010-5-20 01:05 AM 編輯

不我發現還有錯才砍掉...... 那個全域變數$@這樣會造成洗裝
我是覺得是你領獎的方法錯了我發現原本才是正確的因為 80才能領超過 1 不能領

是80樓打完過npc才能領超過1樓都不行

這是傳點npc全部殺死怪才會出現的

4@tower,354,395,0 script ET_Warp_81 45,1,1,{
set @i,80;
warp "4@tower",53,271;
end;
}

複製代碼

我告訢你正確的領獎方法就是你打死 80f的怪過npc @i才是 80
這樣才能領多一樓少一樓都不行

你原本的領獎人員是這樣

e_tower,75,119,5 script 埃蘭之影 997,{
mes "[埃蘭之影]";
mes "找我有事嗎";
next;
if(@i==80)
{
mes "[埃蘭之影]";
mes "原來你到過80樓";
mes "這些東西就送給你了";
getitem 607,100;
set @i,0;
close;
}
else if(@i==90)
{
mes "[埃蘭之影]";
mes "原來你到過90樓";
mes "這些東西就送給你了";
getitem 607,100;
getitem 547,50;
set @i,0;
close;
}
else if(@i==100)
{
mes "[埃蘭之影]";
mes "原來你到過100樓";
mes "這些東西就送給你了";
getitem 7092,1;
getitem 607,200;
getitem 547,100;
set @i,0;
close;
}
else if(@i==101)
{
mes "[埃蘭之影]";
mes "原來你打敗了夜勝魔";
mes "這些東西就送給你了";
getitem 7086,1;
getitem 7092,1;
getitem 607,450;
getitem 547,200;
set @i,0;
close;
}
else
{
mes "[埃蘭之影]";
mes "沒事別打擾我";
close;
}

複製代碼

至於npc_click: npc_id != 0
應該是你自動++npc造成的吧他在執行時++腳本又同時執行別的npc才會出那種錯

DBC · 發表於 2010-5-20 01:23:13

不我發現還有錯才砍掉...... 那個全域變數$@這樣會造成洗裝
我是覺得是你領獎的方法錯了我發現原本才是正確的因為 80才能領超過 1 不能領

那大大你有辦法修正嗎?><"

不然都不能領獎勵了~"~

sinya · 發表於 2010-5-20 02:13:47

本帖最後由 sinya 於 2010-5-20 02:15 AM 編輯

正確的領獎方法 :就是打死 80f的怪過npc @i 才是 80
這樣才能領多一樓少一樓都不行

DBC · 發表於 2010-5-20 02:37:22

正確的領獎方法 :就是打死 80f的怪過npc @i 才是 80
這樣才能領多一樓少一樓都不行
sinya 發表於 2010-5-20 02:13 AM

但是按照原腳本這樣執行

在這模擬器下，好像沒辦法領~"~

sinya · 發表於 2010-5-20 08:14:31

e_tower,75,119,5 script 埃蘭之影 997,{
mes "[埃蘭之影]";
mes "找我有事嗎";
next;
if(@i>=80 && @i<90 && !prize80)
{
mes "[埃蘭之影]";
mes "原來你到過80樓";
mes "這些東西就送給你了";
getitem 607,100;
set @i,0;
set prize80,1;
close;
}
else if(@i>=90 && @i<100 && !prize90)
{
mes "[埃蘭之影]";
mes "原來你到過90樓";
mes "這些東西就送給你了";
getitem 607,100;
getitem 547,50;
set @i,0;
set prize90,1;
close;
}
else if(@i==100)
{
mes "[埃蘭之影]";
mes "原來你到過100樓";
mes "這些東西就送給你了";
getitem 7092,1;
getitem 607,200;
getitem 547,100;
set @i,0;
close;
}
else if(@i==101)
{
mes "[埃蘭之影]";
mes "原來你打敗了夜勝魔";
mes "這些東西就送給你了";
getitem 7086,1;
getitem 7092,1;
getitem 607,450;
getitem 547,200;
set @i,0;
close;
}
else
{
mes "[埃蘭之影]";
mes "沒事別打擾我";
close;
}
}

複製代碼

DBC · 發表於 2010-5-20 14:46:05

目前測試上沒什麼大問題
先謝過sinya大了>"<

		自動登錄	找回密碼
密碼			註冊

無限之塔 腳本問題

瀏覽過的版塊

無限之塔腳本問題