SEAR 10.132 登入腳本問題

change11j

大家好 最近我在載入腳本時有一個問題 就是我想使用一個每日登入送禮物的腳本 但就是沒有辦法出現效果 小黑窗載入時沒有報錯但角色登入後就報錯了 不知道為什麼，可以教教我嗎?我使用的
伺服器 sear 10.132
登入器 20100730a RagexeRE

腳本如下

1. 
   
2. -        script        LOGIN        -1,{
   
3. OnWhisperGlobal:
   
4. OnLoginCmnd:
   
5. OnPCLoginEvent:
   
6.         sleep2 1000 + .Rest * 60000;
   
7.         set .@i, (gettime(7) * 365 * 24 * 60) + (gettime(8) * 24 * 60) + (gettime(3) * 60) +gettime(2);
   
8.         if(.@i >= (#LastDailyReward + .MinWait)){
   
9.                 if(.@i < #LastDailyReward + .MaxWait){
   
10.                         set #DRewardCon, #DRewardCon + 1;
    
11.                 } else {
    
12.                         set #DRewardCon, 1;
    
13.                 }
    
14.                 set .@g, (#DRewardCon > getarraysize(.Rewards$)) ? getarraysize(.Rewards$) : #DRewardCon;
    
15.                 explode(.@TT$,.Rewards$[.@g],"|");
    
16.                 if(.Mode & 1 && .@TT$[4]){
    
17.                         explode(.@XT$, .@TT$[4],":");
    
18.                         //[Note]: I need to figure out a checkweight for all items tired atm lol, for now ill leave it missing
    
19.                         for(set .@x,0; .@x < getarraysize(.@XT$); set .@x,.@x + 2){
    
20.                                 getitem  atoi(.@XT$[.@x]),  atoi(.@XT$[.@x+1]);
    
21.                                 message strcharinfo(0),"Recived "+  .@XT$[.@x+1] +" "+ getitemname( atoi(.@XT$[.@x]));
    
22.                         }
    
23.                 }
    
24.                 if(.Mode & 2 && .@TT$[0]){
    
25.                         setd getd(.@TT$[1]),getd(.@TT$[1]) + atoi(.@TT$[0]);
    
26.                         message strcharinfo(0),"Recived "+ .@TT$[0] +" "+ .@TT$[1];
    
27.                 }
    
28.                 if(.Mode & 4 && (.@TT$[2] || .@TT$[3])) getexp atoi(.@TT$[2]),atoi(.@TT$[3]);
    
29.                 if(.Mode & 8){
    
30.                         for(set .@x,0; .@x < getarraysize(.BuffInfo); set .@x,.@x + 4){
    
31.                                 if(#DRewardCon % .BuffInfo[.@x + 1] == 0) sc_start .BuffInfo[.@x], .BuffInfo[.@x + 2] * 60000, .BuffInfo[.@x + 3];
    
32.                         }
    
33.                 }
    
34.                 message strcharinfo(0),"You have collected your daily reward, for "+#DRewardCon+" day"+((#DRewardCon > 1)?"s":"")+" in a row.";
    
35.                 set #LastDailyReward, .@i;
    
36.         } else {
    
37.                 set .@days,(#LastDailyReward + .MinWait - .@i)/60/24;
    
38.                 set .@hours,((#LastDailyReward + .MinWait - .@i)/60)%24;
    
39.                 set .@mins,(#LastDailyReward + .MinWait - .@i)%60;
    
40.                 message strcharinfo(0),"You have "+ (.@days)?""+.@days+"D:":"" + (.@hours)?""+.@hours+"H:":"" + (.@mins)?""+.@mins+"M:":"" +" till your next reward";
    
41.         }
    
42. end;
    
43. OnInit:
    
44.         //Basic Settings
    
45.         //   1: Item | 2: "Points" | 4: Exp
    
46.         //   8: Gain Buffs Every X Consecutive Days logged in
    
47.         // (a bit value, e.g. 3 = Items & Points from Multi)
    
48.         set .Mode,1 + 2 + 4 + 8;
    
49. 
    
50. 
    
51.         //Minimum Minuets Between Collecting Daily Reward
    
52.         //   Day: 22*60 - 24*60
    
53.         //   Week: 10080
    
54.         set .MinWait,1320;
    
55. 
    
56.         //Minuets Before Lose Consecutive Daily Reward
    
57.         //   Day: 48*60 - 50*60
    
58.         //   Week: 20160
    
59.         set .MaxWait,3000;
    
60. 
    
61.         //Number of mins after logging before collecting prize
    
62.         set .Rest,0;
    
63. 
    
64.         // Consecutive Days Buff
    
65.         // Each buff contains 4 variables (32 Total Max)
    
66.         // <Type>,<Days>,<Duration>,<Rate>, // Buff 1
    
67.         // <Type>,<Days>,<Duration>,<Rate>, // Buff 2
    
68.         //   ...;
    
69.         //
    
70.         //  Example: 188,7,45,3
    
71.         //    -Every 7th consecutive day logged in Player gains +3 Str for 45 mins
    
72.         //
    
73.         //  Type is 188, which references which SC_ to use, SC_INCSTR in this example
    
74.         //     -For a full list of SC_ visit the db/const.txt
    
75.         //  Days is days buff is applied, in this example 7, so every 7th day, 14,21,28....
    
76.         //  Duration is buff duration is Minuits, in this example 45 mins
    
77.         //  Rate is buff strength, in this example player gains 3 Str
    
78.         setarray .BuffInfo        ,188,7,45,3        // +3 Str for 45 Mins Every 7th Day
    
79.                                 ,194,4,45,25        // +25 Hit for 45 Mins Every 4th Day
    
80.                                 ,198,10,60,10        // +10% Hp for 60 Mins Every 10th Day
    
81.                                 ,257,9,120,50;        // +50% Exp for 120 Mins Every 9th Day
    
82. 
    
83.         // Daily Prize items (max 128 days):
    
84.         //   "<Points>|<PointType>|<BaseExp>|<JobExp>|<itemID-1>:<amount-1>:<itemID-2>:<amount-2>...etc", // Day 1
    
85.         //   "<Points>|<PointType>|<BaseExp>|<JobExp>|<itemID-1>:<amount-1>:<itemID-2>:<amount-2>...etc"  // Day 2
    
86.         //   ...;
    
87.         // Total length of any days string must be 255 or shorter
    
88.         // * If players login longer than the last set
    
89.         //   day, they will keep getting the last prize.
    
90.         setarray .Rewards$,
    
91.                 "0|Zeny|0|0|512:1",                        // Day 1: 1 Apple
    
92.                 "0|Zeny|0|0|513:2",                        // Day 2: 2 Bananas
    
93.                 "1000|Zeny",                                // Day 3: 1000 Zeny
    
94.                 "0|Zeny|100|50",                        // Day 4: 100 Base 50 Job Exp
    
95.                 "1|#ExamplePoint|0|0|512:1:513:2";        // Day 5: 1 Apple + 2 Bananas + 1 #ExamplePoint
    
96. end;
    
97. }

複製代碼

map-sever 出現的錯誤如下

jasonwu0319

找到問題了

請你將以下
if(.mode & 1 && .@TT$[4] )

改成
if(.mode & 1 && .@TT$[4] != "")

因為.@TT$[4]是字串而非數值
只有數值可以用if()來判定是否為零

change11j

jasonwu0319 發表於 2014-9-18 05:24 PM
找到問題了

請你將以下

喔喔喔喔 感謝您 我把該改的地方改一改之後果然可以用了 實在十分感謝您