UID52434
帖子
精華
主題
積分27881
現金
積極性
威望
違規
熱心
推廣次數
閱讀權限150
註冊時間2008-1-18
在線時間 小時
最後登錄1970-1-1
TA的每日心情 | 擦汗 2020-10-22 03:17 PM |
---|
簽到天數: 485 天 連續簽到: 1 天 [LV.9]以壇為家II
|
這個腳本多了後台設置,遊戲內裡就有,
可以轉生次數,點數什麼的,
但是不知道為什麼,
有的改了之後還會變回原本預設的樣子,
例如我轉生次數設定3,重開後,會變回預設1,
贈送點數也是,預設50改了之後,重開也是會變回預設的樣子
所以不知道哪出了問題~"~
/************************************************************\
Eathena Script
**************************************************************
【名 稱】職業輔助管理員(Job Assistant Administoator)
【類 型】服務元件
【版 本】1.1.1
【版權所有】相識工作組
【授權費用】免費
【服 務 端】Eathena 12019 及以上
【製作人員】
策劃:七七
編程:♂似曾相識♀
文飾:♂似曾相識♀
製作:♂似曾相識♀
測試:湛藍海風、♂似曾相識♀、violetmoon、eeveekwok、縮水
【簡要說明】
本腳本為 Eathena 服務端專用轉職腳本,功能十分全面,包
括 轉職、轉生、學習新技能、職業租賃、洗點等項,腳本設置
方面包括 控制混轉、指定轉生等級、指定轉生次數、設置轉生
費用、設置轉生增送素質點數、控制混租職業道具、設置租車費
用、設置租鳥費用、設置租鷹費用、設置素質重置費、設置技能
重置費、設置同時重置費等。
【更新日誌】
2008-01-13 1.0.0 腳本完成
2008-01-22 1.0.1 修正轉生後無法轉職的問題
2008-01-26 1.0.2 修正未開啟混轉的情況下,2轉可以混
轉的問題
2008-02-03 1.0.3 修正跆拳無法就職靈媒的問題
1.0.4 修正未開啟混轉的情況下,租大嘴鳥
不檢測騎士騎乘術技能的錯誤
2008-02-18 1.0.5 修正轉初心寶寶後,無法轉職的錯誤
2008-03-07 1.0.6 修正初心寶寶轉超初寶寶的判斷錯誤
2008-05-01 1.0.7 修正轉生不扣錢的錯誤
2008-05-17 1.0.8 修正寶寶職業不能學習新技能的錯誤
2008-05-18 1.0.9 修正個別高階職業無法學習新技能的錯誤
2008-06-13 1.1.0 修正十字刺客可以學到擒拿技能的錯誤
修正超初轉生失敗後租車外觀不正確的錯誤
2008-07-07 1.1.1 修正開啟混轉後進階初心轉寶寶職業後無法
繼續轉職的錯誤
**************************************************************
提示:如果開啟了多次轉生,請修改 exp.conf 的 use_statpoint_table
項目為 no 否則會出現重置點數不正確的情況
\************************************************************/
prontera.gat,155,185,5 script 職業輔助管理員 728,{
mes "[職業輔助管理員]";
mes "請問您有什麼需要幫助的嗎?";
next;
switch(select("我要轉職","我要轉生","學習新技能","租賃職業道具","重置點數",getgmlevel()>90?"後臺設置":"")){
case 1: //轉職
mes "[職業輔助管理員]";
switch(Class){
case 0: //初
case 4001:
case 4023:
if (JobLevel<10||SkillPoint!=0) { mes "您的職業等級不足10級,或有剩餘職業點數,無法轉職!"; close; }
break;
default: //其他
if (JobLevel<40||SkillPoint!=0) { mes "您的基本等級不足40級,或有剩餘職業點數,無法轉職!"; close; }
break;
}
mes "請選擇您要轉的職業。";
next;
switch(Upper){
case 0: //普通職業
switch(Class){
case 0: //初
set @xz,select("劍士","法師","弓手","服侍","商人","盜賊","超初","槍手","忍者","跆拳","初心寶寶");
setarray @jobcode[0],0,1,2,3,4,5,6,23,24,25,4046,4023;
if (@jobcode[@xz]==23&&BaseLevel<40) { mes "[職業輔助管理員]"; mes "您的基本等級不足40級,無法轉職!"; close; }
jobchange @jobcode[@xz];
if (@jobcode[@xz]==4023) { set JobLevel,10; set SkillPoint,0; }
break;
case 1: //劍
set @xz,select("騎士","十字軍");
setarray @jobcode[0],0,7,14;
jobchange @jobcode[@xz];
break;
case 2: //法
set @xz,select("巫師","賢者");
setarray @jobcode[0],0,9,16;
jobchange @jobcode[@xz];
break;
case 3: //弓
set @xz,select("獵人","詩人/舞女");
setarray @jobcode[0],0,11,20;
jobchange @jobcode[@xz]-((@xz==2&&Sex==1)?1:0);
break;
case 4: //服
set @xz,select("牧師","武僧");
setarray @jobcode[0],0,8,15;
jobchange @jobcode[@xz];
break;
case 5: //商
set @xz,select("鐵匠","煉金術士");
setarray @jobcode[0],0,10,18;
jobchange @jobcode[@xz];
break;
case 6: //盜
set @xz,select("刺客","流氓");
setarray @jobcode[0],0,12,17;
jobchange @jobcode[@xz];
break;
case 4046: //拳
set @xz,select("拳聖","靈媒");
setarray @jobcode[0],0,4047,4049;
jobchange @jobcode[@xz];
break;
default: //其他
mes "[職業輔助管理員]";
mes "對不起,沒有您可以轉的職業。";
close;
break;
}
break;
case 1: //進階職業
switch(Class){
case 4001: //初
set @xz,select((Reclass==7||Reclass==14||Reclass==4008||Reclass==4015||Reclass==4030||Reclass==4037||$Job_option[1]==1)?"劍士":"",
(Reclass==9||Reclass==16||Reclass==4010||Reclass==4017||Reclass==4032||Reclass==4039||$Job_option[1]==1)?"法師":"",
(Reclass==11||Reclass==19||Reclass==20||Reclass==4012||Reclass==4020||Reclass==4021||Reclass==4042||Reclass==4043||$Job_option[1]==1)?"弓手":"",
(Reclass==8||Reclass==15||Reclass==4009||Reclass==4016||Reclass==4031||Reclass==4038||$Job_option[1]==1)?"服侍":"",
(Reclass==10||Reclass==18||Reclass==4011||Reclass==4019||Reclass==4033||Reclass==4041||$Job_option[1]==1)?"商人":"",
(Reclass==12||Reclass==17||Reclass==4013||Reclass==4018||Reclass==4035||Reclass==4040||$Job_option[1]==1)?"盜賊":"",
($Job_option[1]==1)?"超初":"",
($Job_option[1]==1)?"槍手":"",
($Job_option[1]==1)?"忍者":"",
($Job_option[1]==1)?"跆拳":"",
($Job_option[1]==1)?"初心寶寶":"");
setarray @jobcode[0],0,4002,4003,4004,4005,4006,4007,23,24,25,4046,4023;
if (@jobcode[@xz]==23&&BaseLevel<40) { mes "[職業輔助管理員]"; mes "您的基本等級不足40級,無法轉職!"; close; }
jobchange @jobcode[@xz];
if (@jobcode[@xz]==4023) { set JobLevel,10; set SkillPoint,0; }
break;
case 4002: //劍
set @xz,select((Reclass==7||Reclass==4008||Reclass==4030||$Job_option[1]==1)?"騎士領主":"",
(Reclass==14||Reclass==4015||Reclass==4037||$Job_option[1]==1)?"聖堂十字軍":"");
setarray @jobcode[0],0,4008,4015;
jobchange @jobcode[@xz];
break;
case 4003: //法
set @xz,select((Reclass==9||Reclass==4010||Reclass==4032||$Job_option[1]==1)?"超魔導師":"",
(Reclass==16||Reclass==4017||Reclass==4039||$Job_option[1]==1)?"智者":"");
setarray @jobcode[0],0,4010,4017;
jobchange @jobcode[@xz];
break;
case 4004: //弓
set @xz,select((Reclass==11||Reclass==4012||Reclass==4034||$Job_option[1]==1)?"神射手":"",
(Reclass==19||Reclass==20||Reclass==4020||Reclass==4021||Reclass==4042||Reclass==4042||$Job_option[1]==1)?"搞笑藝人/冷豔舞姬":"");
setarray @jobcode[0],0,4012,4021;
jobchange @jobcode[@xz]-((@xz==2&&Sex==1)?1:0);
break;
case 4005: //服
set @xz,select((Reclass==8||Reclass==4009||Reclass==4031||$Job_option[1]==1)?"神官":"",
(Reclass==15||Reclass==4016||Reclass==4038||$Job_option[1]==1)?"武術宗師":"");
setarray @jobcode[0],0,4009,4016;
jobchange @jobcode[@xz];
break;
case 4006: //商
set @xz,select((Reclass==10||Reclass==4011||Reclass==4033||$Job_option[1]==1)?"神工匠":"",
(Reclass==18||Reclass==4019||Reclass==4041||$Job_option[1]==1)?"創造者":"");
setarray @jobcode[0],0,4011,4019;
jobchange @jobcode[@xz];
break;
case 4007: //盜
set @xz,select((Reclass==12||Reclass==4013||Reclass==4035||$Job_option[1]==1)?"十字刺客":"",
(Reclass==17||Reclass==4018||Reclass==4040||$Job_option[1]==1)?"神行太保":"");
setarray @jobcode[0],0,4013,4018;
jobchange @jobcode[@xz];
break;
default: //其他
mes "[職業輔助管理員]";
mes "對不起,沒有您可以轉的職業。";
close;
break;
}
break;
case 2: //寶寶職業
switch(Class){
case 4023: //初
set @xz,select("劍士寶寶","法師寶寶","弓手寶寶","服侍寶寶","商人寶寶","盜賊寶寶","超初寶寶");
setarray @jobcode[0],0,4024,4025,4026,4027,4028,4029,4045;
if (@jobcode[@xz]==4045&&BaseLevel<40) { mes "[職業輔助管理員]"; mes "您的基本等級不足40級,無法轉職!"; close; }
jobchange @jobcode[@xz];
break;
case 4024: //劍
set @xz,select("騎士寶寶","十字軍寶寶");
setarray @jobcode[0],0,4030,4037;
jobchange @jobcode[@xz];
break;
case 4025: //法
set @xz,select("巫師寶寶","賢者寶寶");
setarray @jobcode[0],0,4032,4039;
jobchange @jobcode[@xz];
break;
case 4026: //弓
set @xz,select("獵人寶寶","詩人/舞女寶寶");
setarray @jobcode[0],0,4034,4043;
jobchange @jobcode[@xz]-((@xz==2&&Sex==1)?1:0);
break;
case 4027: //服
set @xz,select("牧師寶寶","武僧寶寶");
setarray @jobcode[0],0,4031,4038;
jobchange @jobcode[@xz];
break;
case 4028: //商
set @xz,select("鐵匠寶寶","煉金術士寶寶");
setarray @jobcode[0],0,4033,4041;
jobchange @jobcode[@xz];
break;
case 4029: //盜
set @xz,select("刺客寶寶","流氓寶寶");
setarray @jobcode[0],0,4035,4040;
jobchange @jobcode[@xz];
break;
default: //其他
mes "[職業輔助管理員]";
mes "對不起,沒有您可以轉的職業。";
close;
break;
}
break;
}
for (set @t,1;@t<11;set @t,@t+1) unequip @t;
mes "[職業輔助管理員]";
mes "恭喜您轉職成功!";
break;
case 2: //轉生
mes "[職業輔助管理員]";
if ($Job_option[3]>1) mes "您目前的轉生次數為"+metempsychosis+"次,";
mes "確定要轉生嗎?";
next;
menu "確定轉生",-;
mes "[職業輔助管理員]";
if (metempsychosis>=$Job_option[3]) { mes "您已經無法再轉生了!"; close; }
if (BaseLevel<$Job_option[2]||(Class>=0&&Class<=6)||(Class>=4001&&Class<=4007)||(Class>=4023&&Class<=4029)||JobLevel<50) {
mes "對不起,您的等級不夠"+$Job_option[2]+"級或職業等級不夠50級或不是二轉職業。";
close;
}
if (checkcart()>0||checkfalcon()>0||checkriding()>0) { mes "請您把手推車、鷹、鳥移除。"; close; }
if (Zeny<$Job_option[4]) { mes "我需要"+$Job_option[4]+"Zeny。"; close; }
if ($Job_option[1]==0 && (Class==23||Class==24||Class==25||Class>=4023)) { mes "對不起,您的職業不能轉生。"; close; }
set Zeny,Zeny-$Job_option[4];
set Reclass,Class;
setoption 0;
jobchange 0,1;
resetskill;
resetstatus;
set SkillPoint,0;
set StatusPoint,0;
set BaseLevel,1;
set JobLevel,1;
set BaseExp,0;
set JobExp,0;
for (set @t,1;@t<11;set @t,@t+1) unequip @t;
set metempsychosis,metempsychosis+1;
if ($Job_option[3]>=2) set StatusPoint,$Job_option[5]*metempsychosis+100;
if ($Job_option[3]==1) set StatusPoint,148;
mes "恭喜您轉生成功。";
break;
case 3: //技能
mes "[職業輔助管理員]";
mes "我是新技能指導員,您將會在我這裏學到每一個職業的新技能";
mes "當然,必須要對應職業才可以學到該技能咯。";
next;
switch(class){
case 0: //初心
case 23:
case 4001:
case 4023:
case 4045:
if (getskilllv(142)==0) skill 142,1,0;
if (getskilllv(143)==0) skill 143,1,0;
break;
case 1: //劍士
case 4002:
case 14: //十字軍
case 21:
case 4015:
case 4022:
case 7: //騎士
case 13:
case 4008:
case 4014:
case 4024:
case 4030:
case 4037:
case 4036:
case 4044:
if (getskilllv(144)==0) skill 144,1,0;
if (getskilllv(145)==0) skill 145,1,0;
if (getskilllv(146)==0) skill 146,1,0;
if (getskilllv(1001)==0 && Class==7) skill 1001,1,0;
if (getskilllv(1001)==0 && Class==13) skill 1001,1,0;
if (getskilllv(1001)==0 && Class==4008) skill 1001,1,0;
if (getskilllv(1001)==0 && Class==4014) skill 1001,1,0;
if (getskilllv(1002)==0 && Class==14) skill 1002,1,0;
if (getskilllv(1002)==0 && Class==21) skill 1002,1,0;
if (getskilllv(1002)==0 && Class==4015) skill 1002,1,0;
if (getskilllv(1002)==0 && Class==4022) skill 1002,1,0;
break;
case 2: //魔法師
case 4003:
case 9: //巫師
case 4010:
case 4017: //賢者
case 16:
case 4025:
case 4032:
case 4039:
if (getskilllv(157)==0) skill 157,1,0;
if (getskilllv(1006)==0 && Class==9) skill 1006,1,0;
if (getskilllv(1006)==0 && Class==4010) skill 1006,1,0;
if (getskilllv(1007)==0 && Class==16) skill 1007,1,0;
if (getskilllv(1007)==0 && Class==4017) skill 1007,1,0;
if ((getskilllv(1008)+getskilllv(1017)+getskilllv(1018)+getskilllv(1019)==0) && Class==16) {
mes "[職業輔助管理員]";
mes "這裏有四種技能可以學習!";
mes "^ff2030但只能學習其中的一種^000000";
mes "您要學習哪一種呢?";
next;
switch(select("水屬性轉換","地屬性轉換","火屬性轉換","風屬性轉換")) {
case 1: skill 1008,1,0; break;
case 2: skill 1017,1,0; break;
case 3: skill 1018,1,0; break;
case 4: skill 1019,1,0; break;
}
}
if ((getskilllv(1008)+getskilllv(1017)+getskilllv(1018)+getskilllv(1019)==0) && Class==4017) {
mes "[職業輔助管理員]";
mes "這裏有四種技能可以學習!";
mes "^ff2030但只能學習其中的一種^000000";
mes "您要學習哪一種呢?";
next;
switch(select("水屬性轉換","地屬性轉換","火屬性轉換","風屬性轉換")) {
case 1: skill 1008,1,0; break;
case 2: skill 1017,1,0; break;
case 3: skill 1018,1,0; break;
case 4: skill 1019,1,0; break;
}
}
break;
case 3: //弓箭手
case 4004:
case 11: //獵人
case 4012:
case 19: //吟游詩人
case 4020:
case 20: //舞娘
case 4021:
case 4026:
case 4034:
case 4042:
case 4043:
if (getskilllv(147)==0) skill 147,1,0;
if (getskilllv(148)==0) skill 148,1,0;
if (getskilllv(1009)==0 && Class==11) skill 1009,1,0;
if (getskilllv(1009)==0 && Class==4012) skill 1009,1,0;
if (getskilllv(1010)==0 && Class==19) skill 1010,1,0;
if (getskilllv(1010)==0 && Class==4020) skill 1010,1,0;
if (getskilllv(1011)==0 && Class==20) skill 1011,1,0;
if (getskilllv(1011)==0 && Class==4021) skill 1011,1,0;
break;
case 4: //服事
case 4005:
case 8: //祭司
case 4009:
case 15: //武道家
case 4016:
case 4027:
case 4031:
case 4038:
if (getskilllv(156)==0) skill 156,1,0;
if (getskilllv(1014)==0 && Class==8) skill 1014,1,0;
if (getskilllv(1014)==0 && Class==4009) skill 1014,1,0;
if (getskilllv(1015)==0 && Class==15) skill 1015,1,0;
if (getskilllv(1015)==0 && Class==4016) skill 1015,1,0;
if (getskilllv(1016)==0 && Class==15) skill 1016,1,0;
if (getskilllv(1016)==0 && Class==4016) skill 1016,1,0;
break;
case 5: //商人
case 4006:
case 10: //鐵匠
case 4011:
case 18: //煉金
case 4019:
case 4028:
case 4033:
case 4041:
if (getskilllv(153)==0) skill 153,1,0;
if (getskilllv(154)==0) skill 154,1,0;
if (getskilllv(155)==0) skill 155,1,0;
if (getskilllv(1012)==0 && Class==10) skill 1012,1,0;
if (getskilllv(1012)==0 && Class==4011) skill 1012,1,0;
if (getskilllv(1013)==0 && Class==10) skill 1013,1,0;
if (getskilllv(1013)==0 && Class==4011) skill 1013,1,0;
if (getskilllv(238)==0 && Class==18) skill 238,1,0;
if (getskilllv(238)==0 && Class==4019) skill 238,1,0;
break;
case 6: //盜賊
case 4007:
case 12: //刺客
case 4013:
case 17: //流氓
case 4018:
case 4029:
case 4035:
case 4040:
if (getskilllv(149)==0) skill 149,1,0;
if (getskilllv(150)==0) skill 150,1,0;
if (getskilllv(151)==0) skill 151,1,0;
if (getskilllv(152)==0) skill 152,1,0;
if (getskilllv(1003)==0 && Class==12) skill 1003,1,0;
if (getskilllv(1003)==0 && Class==4013) skill 1003,1,0;
if (getskilllv(1004)==0 && Class==12) skill 1004,1,0;
if (getskilllv(1004)==0 && Class==4013) skill 1004,1,0;
if (getskilllv(1005)==0 && Class==17) skill 1005,1,0;
if (getskilllv(1005)==0 && Class==4018) skill 1005,1,0;
break;
case 4048: //媒靈
case 4047: //拳聖
case 4049: //悟靈士
case 4046: //跆拳道
if (getskilllv(493)==0) skill 493,1,0;
break;
default: //槍手
mes "[職業輔助管理員]";
mes "這個職業暫時沒有新技能學習!";
close;
}
mes "[職業輔助管理員]";
mes "我已經把新技能教給您了,打開技能表看一下吧!";
break;
case 4: //租賃
mes "[職業輔助管理員]";
if (checkcart()) { mes "您已經裝備了手推車"; close; }
if (checkriding()) { mes "您不是有鳥騎了嗎?"; close; }
if (checkfalcon()) { mes "您不是有鷹了嗎?"; close; }
switch($Job_option[6]){
case 0: //不可混租
switch(Class){
case 5: //車
case 10:
case 18:
case 23:
case 4006:
case 4011:
case 4019:
case 4028:
case 4033:
case 4041:
case 4045:
if (getskilllv(39)<1) { mes "抱歉!您沒有學會手推車使用這項技能。"; close; }
if (Zeny<$Job_option[7]) { mes "很抱歉,您的金錢不足。這至少需要 "+$Job_option[7]+" Zeny。"; close; }
set Zeny,Zeny-$Job_option[7];
if (Class==23) setcart 4;
else setcart 1;
mes "給您的小車。";
break;
case 7: //鳥
case 14:
case 4008:
case 4015:
case 4030:
case 4037:
if (getskilllv(63)<1) { mes "抱歉!您沒有學會騎乘術這項技能。"; close; }
if (Zeny<$Job_option[8]) { mes "很抱歉,您的金錢不足。這至少需要 "+$Job_option[8]+" Zeny。"; close; }
set Zeny,Zeny-$Job_option[8];
mes "給您的大鳥。";
setriding;
break;
case 11: //鷹
case 4012:
case 4034:
if (getskilllv(127)<1) { mes "抱歉!您沒有學會訓鷹術這項技能。"; close; }
if (Zeny<$Job_option[9]) { mes "很抱歉,您的金錢不足。這至少需要 "+$Job_option[9]+" Zeny。"; close; }
set Zeny,Zeny-$Job_option[9];
mes "給您的獵鷹。";
setfalcon;
break;
default:
mes "對不起,沒有您這個職業的道具租賃服務。";
close;
break;
}
break;
case 1: //可以混租
mes "請選擇您要租賃的道具。";
next;
switch(select("租賃手推車","租賃大鳥","租賃獵鷹")){
case 1: //車
if (Zeny<$Job_option[7]) { mes "很抱歉,您的金錢不足。這至少需要 "+$Job_option[7]+" Zeny。"; close; }
set Zeny,Zeny-$Job_option[7];
setoption 8;
mes "給您的小車。";
break;
case 2: //鳥
if (Zeny<$Job_option[8]) { mes "很抱歉,您的金錢不足。這至少需要 "+$Job_option[8]+" Zeny。"; close; }
set Zeny,Zeny-$Job_option[8];
mes "給您的大鳥。";
setoption 32;
break;
case 3: //鷹
if (Zeny<$Job_option[9]) { mes "很抱歉,您的金錢不足。這至少需要 "+$Job_option[9]+" Zeny。"; close; }
set Zeny,Zeny-$Job_option[9];
mes "給您的獵鷹。";
setoption 16;
break;
}
break;
}
break;
case 5: //重置
mes "[職業輔助管理員]";
mes "您想重置什麼呢?";
next;
set @menu,select("技能點(費用"+$Job_option[10]+")","屬性點(費用"+$Job_option[11]+")","技能點和屬性點(費用"+$Job_option[12]+")");
mes "[職業輔助管理員]";
switch(@menu) {
case 1: set @price,$Job_option[10]; break;
case 2: set @price,$Job_option[11]; break;
case 3: set @price,$Job_option[12]; break;
}
if (Zeny<@price) { mes "您好像沒那麼多錢。"; close; }
set Zeny,Zeny-@price;
switch(@menu) {
case 1: resetskill; break;
case 2: resetstatus; break;
case 3: resetskill; resetstatus; break;
}
mes "重置成功,這次可不要再加錯了哦~";
close;
break;
case 6: //後臺
mes "[職業輔助管理員]";
mes "請問管理員有什麼需要修改的嗎?";
next;
set @op,select("可否混轉["+(($Job_option[1]==0)?"不可":"可以")+"]",
"轉生等級["+$Job_option[2]+"]",
"轉生次數["+$Job_option[3]+"]",
"轉生費用["+$Job_option[4]+"]",
"轉生贈點["+$Job_option[5]+"]",
"可否混租["+(($Job_option[6]==0)?"不可":"可以")+"]",
"租車費用["+$Job_option[7]+"]",
"租鳥費用["+$Job_option[8]+"]",
"租鷹費用["+$Job_option[9]+"]",
"素質重置費["+$Job_option[10]+"]",
"技能重置費["+$Job_option[11]+"]",
"同時重置費["+$Job_option[12]+"]");
setarray @word$[0],"","可否混轉","轉生等級","轉生次數","轉生費用","轉生贈點","可否混租","租車費用","租鳥費用","租鷹費用","素質重置費","技能重置費","同時重置費";
mes "[職業輔助管理員]";
mes "請"+((@op==1||@op==6)?"選擇":"輸入")+@word$[@op]+"。";
if (@op!=1&&@op!=5) mes "輸入範圍:1~1000000000";
next;
switch(@op){
case 1:
case 6:
set $Job_option[@op],select("不可","可以")-1;
break;
default:
input @num;
if (@num>1000000000||@num<1) { mes "[職業輔助管理員]"; mes "輸入的數值不在允許範圍內。"; close; }
set $Job_option[@op],@num;
break;
}
mes "[職業輔助管理員]";
mes "設置修改成功!";
break;
}
close;
end;
OnInit:
//判斷初始化(此項勿動),混轉(1可),轉生等級,轉生次數,轉生費用,轉生增點(次數大於1有效),混租賃(1可),租車費用,租鳥費用,租鷹費用,素質重置費,技能重置費,同時重置費
if ($Job_option[0]==0) setarray $Job_option[0],1,0,99,1,1285000,50,0,800,2500,2500,800000,500000,1000000;
end;
}
[ 本帖最後由 逍遙天子 於 2008-11-8 02:07 PM 編輯 ] |
本帖子中包含更多資源
您需要 登錄 才可以下載或查看,沒有帳號?註冊
x
|