ea有關打動npc的腳本

q168761999

哪個大大可以幫我翻譯一下我的打動npc的腳本

這是政府的不過我都看不懂@@

我想調他過的機率幫我翻譯一下謝謝

以下是死神之劍的打動腳本

case 7: callfunc "Func_Socket",2,1169,1179,40,51,1000,984,5,999,10; break;


有勞各位大大了

lendlice0001

#1
請 po 出 function 「Func_Socket」

q168761999

function        script        Func_Socket        {
        mes "[雷亞布連]";
        mes getitemname(getarg(1))+"...很好! 那個的話，";
        if (getarg(0) == 1) {
                mes "^FF0000費用為"+getarg(5) / 10+"萬金幣，材料是"+getitemname(getarg(6))+" "+getarg(7)+"個，";
        }
        else if (getarg(0) == 2) {
                mes "^FF0000費用為"+getarg(5) / 10+"萬金幣，材料是";
                mes "^FF0000"+getitemname(getarg(6))+" "+getarg(7)+"個和"+getitemname(getarg(8))+" "+getarg(9)+"個，";
        }
        mes "^FF0000"+getitemname(getarg(1))+"理所當然";
        mes "^FF0000也要準備妥當^000000";
        next;
        mes "[雷亞布連]";
        mes "材料和費用都帶齊了嗎?";
        mes "還有萬一失敗時材料和裝備";
        mes "都會消失，即使洞成功了，";
        mes "精鍊值或已插上去的卡片，";
        mes "都會消失不見，要銘記了";
        next;
        if ( select("我要打洞","改下次吧") == 2 ) {
                mes "[雷亞布連]";
                mes "那麼歡迎下次再來";
                close;
        }
        switch(getarg(0)) {
                case 1:               
                        if((Zeny < getarg(5)*1000) || (countitem(getarg(6)) < getarg(7)) || (!countitem(getarg(1)))) {
                                mes "[雷亞布連]";
                                mes "那個... 材有些料不足，";
                                mes "請你再確認一下吧";
                                close;
                        }
                        break;
        
                case 2:
                        if((Zeny < getarg(5)*1000) || (countitem(getarg(6)) < getarg(7)) || (countitem(getarg(8)) < getarg(9)) || (!countitem(getarg(1)))) {
                                mes "[雷亞布連]";
                                mes "那個... 材有些料不足，";
                                mes "請你再確認一下吧";
                                close;
                        }
                        break;
        }
        mes "[雷亞布連]";
        mes "那麼開始進行吧? 請你";
        mes "祈禱能圓滿成功，呵呵";
        next;
        set .@socketrand,rand(1,100);
        if((.@socketrand > getarg(3)) && (.@socketrand < getarg(4))) {
                specialeffect EF_LORD;
                mes "[雷亞布連]";
                mes "OK... 似乎非常順利，成功!";
                mes "洞打的很漂亮呢? 恭喜你啦";
                delitem getarg(1),1;
                delitem getarg(6),getarg(7);
                if(getarg(0) == 2) delitem getarg(8),getarg(9);
                set Zeny,Zeny - getarg(5)*1000;
                getitem getarg(2),1;
                next;
                mes "[雷亞布連]";
                mes "那麼歡迎下次再利用囉";
                close;
        }
        else {
                specialeffect EF_SUI_EXPLOSION;
                mes "[雷亞布連]";
                mes "嗚... 拍謝喔，失敗了...";
                mes "都怪運氣不好.. 打洞難免";
                mes "會有失敗的時候，嗯..";
                mes "雖然這次失敗了，但相信";
                mes "下次一定可以成功滴";
                delitem getarg(1),1;
                delitem getarg(6),getarg(7);
                if(getarg(0) == 2) delitem getarg(8),getarg(9);
                set Zeny,Zeny - getarg(5)*1000;
                next;
                mes "[雷亞布連]";
                mes "那麼歡迎下次再利用囉";
                close;



感謝大大的回文~~!

我po上了

pan00017

if((.@socketrand > getarg(3)) && (.@socketrand < getarg(4)))

lendlice0001

#3
case 7: callfunc "Func_Socket",2,1169,1179,40,51,1000,984,5,999,10; break;

q168761999

4# pan00017

大大你所說的要改的是哪個地方= =


我還是看不懂

克雅

整合一下
set .@socketrand,rand(1,100);
這排是他會隨機由1~100取一個數字

if((.@socketrand > getarg(3)) && (.@socketrand < getarg(4)))
這排是指定他 要是在> 3號  <4號就 算通過

case 7: callfunc "Func_Socket",2,1169,1179,40,51,1000,984,5,999,10; break;
至於 何謂三號 四號 就是五樓說的 40 跟51
也就是 他隨機的數字 為 比三號(40)大     比四號(51)小 就成功
懂了嗎?